C:\to_server\website\mrdcl-learning.com\mrdcl_files\TAB-06\run.stp
start data,
serial number in columns 1-3,
card characters 100,
ds $q1=$4/1-9,0,e,
x='Brand A;
Brand B;
Brand C;
Brand D;
Brand E;
Brand F;
Brand G;
Brand H;
Brand I;
Brand J;
None',
xt='Q1 Favourite brand',
dm $q2=$5-14,e,
x=$q1,
xt='Q2 Other brands considered',
dm $q1q2=$q1.or.$q2,
dm $q1q2=$q1q2/1-10,e,
x=$q1,
xt='Q1/Q2 All brands considered',
dm $q3=$15-24,e,
x=$q1,
xt='Q3 Brand seen advertised',
dm $q1q2_and_q3=$q1q2.and.$q3,
dm $q1q2_and_q3=$q1q2_and_q3/1-10,e,
x=$q1,
xt='Q1/Q3 Brand connsidered and seen advertised',
dm $q1q2_not_q3=$q1q2.and..not.$q3,
dm $q1q2_not_q3=$q1q2_not_q3/1-10,e,
x=$q1,
xt='Q1/Q3 Brand connsidered and not seen advertised',
ds $gender=$25/1,2,
x='Male;
Female',
xt='Gender',
ds $age=$26/1-3,
x='16-34;
35-54;
55+',
xt='Age',
f=ifbu/adf,
di $number_in_household=$27-28,
xt='Number in household',
ds $vnumber_in_household=$number_in_household/1,2,3..5,>5,e,
x='1;
2;
3 to 5;
More than 5;
Not stated<z>',
xt='Number in household',
dm $mybanner=$gender,$age/1,2..3,$number_in_household/1..2,>2,
h='Gender\
Male;
Female;
Age\
16-34;
35+;
Number in h/hold\
1-2;
3+',
finish data,
start tables,
global bt#='All respondents',
f=dpr1/clw7,
f=caz'0',
%jh='Brand Awareness Project<jc>',
%jf='Produced by MRDC Software on <&dd>/<&mm>/<&yy> at <&hh>:<&nn>:<&ss><jc>',
%avg='Mean score<d2>',
select banner $mybanner,
t#1(f=brs/dpr0)=$q1 * ,
t#2(f=dpr0)=$q1 * $q2,
f=dpr0,
t#3=$q2 * ,
t#4=$q1q2 * ,
t#5=$q3 * ,
f=dpr2,
if $gender/2,t#6=$q3 * ,
bt='All females',
t#7=$q1q2_and_q3 * ,
t#8=$vnumber_in_household *,
+t#8x=@ $number_in_household *,
finish tables,
